access 2003 to windows 10 64 bit

[M2M]

มีทานไหนเจอปัญหาการนำเอา File .MDB ที่เป็นของ2003 ไป run กับ Windows รุ่นใหม่ ที่เป็น 64 bit บ้างมั้ยครับ

[สันติสุข]

ค้นหาในเวปด้วยคำว่า "64 bit"  มีถามกันพอสมควร

[nonc31]

ต้องทำ code เพิ่มอีกนิดหน่อย จาก Private Declare Function  เป็น  Private Declare PtrSafe Function

Option Compare Database
      Private Const LOCALE_SSHORTDATE = &H1F
      Private Const WM_SETTINGCHANGE = &H1A
      Private Const HWND_BROADCAST = &HFFFF&
#If VBA7 Then 'access 64บิต
      Private Declare PtrSafe Function SetLocaleInfo Lib "kernel32" Alias "SetLocaleInfoA" (ByVal Locale As Long, ByVal LCType As Long, ByVal lpLCData As String) As Boolean
      Private Declare PtrSafe Function PostMessage Lib "User32" Alias "PostMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
      Private Declare PtrSafe Function GetSystemDefaultLCID Lib "kernel32" () As Long
#Else
      Private Declare Function SetLocaleInfo Lib "kernel32" Alias "SetLocaleInfoA" (ByVal Locale As Long, ByVal LCType As Long, ByVal lpLCData As String) As Boolean
      Private Declare Function PostMessage Lib "User32" Alias "PostMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
      Private Declare Function GetSystemDefaultLCID Lib "kernel32" () As Long
#End If
 

Function setdate()  'ตรวจสอบรูปแบบวันที่ dd/mm/yyyy
    Dim dwLCID As Long
            dwLCID = GetSystemDefaultLCID()
           
        If SetLocaleInfo(dwLCID, LOCALE_SSHORTDATE, "dd/MM/yyyy") = False Then
            MsgBox "ผิดพลาด", vbCritical, "Error"
        End If
            PostMessage HWND_BROADCAST, WM_SETTINGCHANGE, 0, 0
End Function

[มาลี]

อ. nonc31 โค๊ดนี้นำไปใช้อย่างไรคะ
เมื่อใช้โค๊ดนี้แล้ว ช่วยให้สามารถเอาไฟล์ 32bit ไปใช้กับ 64 bit ได้เลยใช่ไหมคะ
ขอคำแนะนำเพิ่มเติมด้วยค่ะ

[nonc31]

ได้เลยครับคุณมาลี  เพราะผมเขียนโค๊ดด้วย 2003 32บิต (VBA 6.3) ให้ใช้กับ 2013 64บิต (VBA 7.1)
ก่อนหน้านี้ก็คิดหนักอยู่ครับ  โค๊ดมันจะ Error ตรงการเรียกใช้ API ของวินโดว์เท่านั้นล่ะ

[มาลี]

โค๊ดดังกล่าวนำไปใส่ตรงไหนคะ
ต้องสร้างโมดูลหรืออย่างไรคะอาจารย์
ขอคำแนะนำด้วยค่ะ

[nonc31]

[มาลี]

ขอบคุณค่ะอาจารย์

[มาลี]

ขออนุญาตสอบถามเพิ่มเติมอีกหน่อยนะคะอาจารย์
โค๊ดดังกล่าวเราต้องใส่ทุกๆฟอร์มที่มีการเรียกใช้apiใช่ไหมคะ
สมมติถ้าเป็นอย่างนั้น เราจะมีวิธีดักตั้งแต่ตอนเปิดครั้งแรกเพียงครั้งเดียวได้หรือเปล่าคะ

[สันติสุข]

สร้าง Module ขึ้นมา 1 ตัว แล้วแทนที่จะใส่ Private Declare PtrSafe ... ก็ใส่เป็น Public Declare PtrSafe ... แทนครับ วางไว้ที่เดียว จะได้เรียกใช้จากที่ไหนก็ได้

[มาลี]

ขอคุณมากค่ะอาจารย์

[มาลี]

ไปไม่รอดค่ะอาจารย์
ตอนนี้หนูทำโมดูลเสร้จแล้ว แต่มาติดก็ตอนที่จะเรียกใช้โมดูลจากในฟอร์มนี่แหละค่ะ ไม่ทราบต้องเรียกอย่างไร
รบกวนอาจาย์แนะนำหรือจะช่วยทำไฟล์ตัวอย่างให้ได้ลองแกะศึกษาดู ก็จะเป็นพระคุณอย่างยิ่งค่ะอาจารย์
ขอขอบคุณนะคะ

[มาลี]

https://thai-access.com/tiupld/images/q0brmu-e52a41.png

[มาลี]

[สันติสุข]

สร้างโมดูล แล้วใส่โค้ดข้างล่างนี้ เวลาเรียกใช้ ก็แค่สั่ง setdate เท่านั้น  โค้ดมีความแตกต่างนิดหน่อยจากโค้ดของคุณ nonc31 นะครับ คือไม่มีการเช็ค compiler directive VBA7 เพราะ VBA7 ไม่ได้เป็นการเช็คว่าระบบเป็น 32 หรือ 64 bit  ถ้าจะเช็คต้องใช้ compiler directive Win64  แต่ยังไงก็ตาม API 3 ตัวนี้ไม่มีความจำเป็นต้องเช็ค เพียงแค่ตบแต่งบางอย่าง ก็จะใช้ได้ทั้ง 32 และ 64 bit แต่ใช้สำหรับ Access 2007 หรือสูงกว่าเท่านั้นนะครับ

เนื่องจากว่า ผมเข้าใจว่าการเรียกใช้ API ทั้ง 3 ตัวนี้ ถูกเรียกจาก procedure setdate เท่านั้น ดังนั้นไม่จำเป็นต้องกำหนดเป็น Pubic ที่คำสั่ง Declare ก็ได้ แต่ใส่ไว้ที่ procedure setdate ที่เดียวก็ได้ครับ

ยังไงก็ตาม ผมลองโค้ดนี้ในเครื่องของผมตอนนี้ จะไม่ได้ผลทันที ต้องปิด Access แล้วเข้าใหม่  ส่วนที่แสดงเวลาบนหน้าเดสก์ท็อปเองก็ไม่เปลี่ยน แต่ฟอร์แมทภายในเปลี่ยน ไม่ทราบเหมือนกันว่าเป็นเพราะอะไร

โค๊ด: [Select]

Option Compare Database
Option Explicit

Private Const LOCALE_SSHORTDATE = &H1F
Private Const WM_SETTINGCHANGE = &H1A
Private Const HWND_BROADCAST = &HFFFF&

Declare PtrSafe Function SetLocaleInfo Lib "kernel32" Alias "SetLocaleInfoA" (ByVal Locale As Long, ByVal LCType As Long, ByVal lpLCData As String) As Long
Declare PtrSafe Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hwnd As LongPtr, ByVal wMsg As Long, ByVal wParam As LongPtr, ByVal lParam As LongPtr) As Long
Declare PtrSafe Function GetSystemDefaultLCID Lib "kernel32" () As Long

Public Function setdate()
    Dim dwLCID As Long
   
    dwLCID = GetSystemDefaultLCID()
    If SetLocaleInfo(dwLCID, LOCALE_SSHORTDATE, "dd/MM/yyyy") = 0 Then
        MsgBox "ผิดพลาด", vbCritical, "Error"
        Exit Function
    End If
   
    PostMessage HWND_BROADCAST, WM_SETTINGCHANGE, 0, 0
End Function


[มาลี]

ขอขอบคุณอาจารย์ทั้งสองท่านนะคะ
หนูจะคอยติดตามและพยายามศึกษาต่อไปค่ะ

[สันติสุข]

ผมตรวจสอบเพิ่มเติมโดยเปิด Access แล้วสร้างเท็กซ์บ็อกซ์ที่มี Format เป็น Short Date  แล้วเปลี่ยนฟอร์แมทของ short date ใน windows taskbar ด้วยมือ  กลับมาที่ Access ก็ยังคง Format เดิมไม่เปลี่ยนตามครับ ต่อให้ Close Database แล้วเปิดใหม่ก็ยังเป็น Format เดิม  ต้องปิด Access ไปเลยแล้วค่อยเปิด Access ใหม่  Format ถึงจะเปลี่ยนตาม 

ผมแนะนำว่า ให้เช็คฟอร์แมทของ Short Date ดีกว่าว่าเป็นไปตามที่เราต้องการหรือไม่ ถ้าไม่ใช่ก็ให้ปิด Access ไป  ให้ผู้ใช้เปลี่ยนด้วยมือเอาเอง วิธีการเช็คก็คือสั่งในโค้ดที่เริ่มต้นของระบบ และเช็คด้วยวันที่ 29 กพ. ค.ศ. 2020

โค๊ด: [Select]

If format$(DateSerial(2020,2,29),"Short Date")  <> "29/02/2020" Then
   MsgBox แจ้งให้ผู้ใช้ไปเปลี่ยนฟอร์มแมทเองก่อน
   Application.Quit
End If

[nonc31]

Control Panel > Region >Formate ต้องเป็น Thai (Thailand) Currnet language ต้องเป็น Thai (Thailand)

Option Compare Database
      Private Const LOCALE_SSHORTDATE = &H1F
      Private Const WM_SETTINGCHANGE = &H1A
      Private Const HWND_BROADCAST = &HFFFF&
#If VBA7 Then
      Private Declare PtrSafe Function SetLocaleInfo Lib "kernel32" Alias "SetLocaleInfoA" (ByVal Locale As Long, ByVal LCType As Long, ByVal lpLCData As String) As Boolean
      Private Declare PtrSafe Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
      Private Declare PtrSafe Function GetSystemDefaultLCID Lib "kernel32" () As Long
#Else
      Private Declare Function SetLocaleInfo Lib "kernel32" Alias "SetLocaleInfoA" (ByVal Locale As Long, ByVal LCType As Long, ByVal lpLCData As String) As Boolean
      Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
      Private Declare Function GetSystemDefaultLCID Lib "kernel32" () As Long
#End If
     
Function setdate() 'ใช้เปลี่ยนรูปแบบวันที่
    Dim dwLCID As Long
            dwLCID = GetSystemDefaultLCID()
           
        If SetLocaleInfo(dwLCID, LOCALE_SSHORTDATE, "dd/MM/yyyy") = False Then
            MsgBox "รูปแบบวันที่ไม่ใช่ dd/MM/yyyy", vbCritical, "Error"
        End If
            PostMessage HWND_BROADCAST, WM_SETTINGCHANGE, 0, 0
End Function

กระทู้ถามว่าไงเนี๊ย