ขอสอบถามเรื่องการอัพเดทข้อมูลครับ

[nainumgame]

อยากจะสอบถามครับ คือว่าผมต้องการอัพเดทยอดขายโดยบันทึกยอดขายประจำวัน โดยสามารถบันทึกได้ตลอดและอัพเดทข้อมูลเป็นปัจจุบันด้วย

ซึ่งผมเขียนโค้ดตามนี้ครับ
Private Sub Cmd_Report_Up_Click()
On Error Resume Next
If MsgBox("คุณต้องการบันทึกยอดขาย ใช่ หรือ ไม่", vbInformation + vbYesNo, "แจ้งเตือน") = vbYes Then
CurrentDb.Execute "INSERT INTO Report_Sale(R_DATE, R_PRICE, R_SALE, R_CARD,R_CREDIT,R_IN_CREDIT,R_GP)" & _
"values('" & Me.Date_Re & "','" & Me.t01 & "','" & Me.t02 & "','" & Me.t03 & "','" & Me.t04 & "','" & Me.t05 & "','" & Me.t06 & "')"
End If
End Sub
แต่ปัญหามันคือ เมื่อผมขายสินค้าไปเพิ่ม แล้วบันทึกใหม่มันไม่อัพเดทยอดขายให้
ไม่ทราบว่าผมต้องเขียนโค้ดอย่างไงครับ
รบกวนอาจารย์ด้วยครับ

[สันติสุข]

1 ที่เห็นแน่ๆหนึ่งจุดคือ CurrentDb.Execute "INSERT INTO Report_Sale(R_DATE, R_PRICE, R_SALE, R_CARD,R_CREDIT,R_IN_CREDIT,R_GP)" & _ ให้เพิ่มอย่างน้อย 1 ช่องว่างที่ด้านหลังวงเล็บครับ

2. ที่ท้ายคำสั่ง CurrentDB.Execute ... Me.t06 & "')" ควรใส่ ,dbFailOnError ต่อท้ายด้วย

3. ที่อาจเกิดปัญหาต่อไปได้ ซึ่งขึ้นกับประเภท (Data Type) ของแต่ละฟิลด์ (R_DATE, R_PRICE, R_SALE, R_CARD,R_CREDIT,R_IN_CREDIT,R_GP) ว่าเป็นประเภทอะไร เพราะคำสั่งคุณมีเครื่องหมาย '  ครอบข้อมูลที่จะเพิ่มทุกฟิลด์ ซึ่งหมายถึงทุกฟิลด์มีประเภทเป็น Text ทั้งหมดเลย แต่ดูแล้วไม่น่าจะเป็นอย่างนั้น ที่ถูกต้องคือ ถ้าเป็นฟิลด์ Number ก็ไม่ต้องมีเครื่องหมาย ' คั่น  ในขณะที่ประเภทของฟิลด์ Date ต้องใช้เครื่องหมาย # คั่น (ประเภทของฟิลด์ต้องดูที่ตัวเทเบิล ไม่ใช่ดูที่เราป้อนอะไรเข้าไปบนหน้าฟอร์ม)

4. ให้เอาบรรทัด On Error Resume Next ออก เพราะคำสั่งนี้จะทำให้ Access ไม่สนใจ error ที่เกิดขึ้น ถ้าเกิด error มันก็จะทำงานคำสั่งถัดไปเลย เราจึงไม่รู้ว่าจริงๆแล้วมี error อะไรเกิดขึ้นบ้าง

[nainumgame]

ขอบคุณครับอาจารย์ผมลองทำตามแล้วมันได้อยู่ครับ แต่มันบันทึกเป็นไฟล์ใหม่ ผมอยากให้มันมันทึกซ้ำวันที่อันเดิมครับ เราต้องใส่เงื่อนไขอย่างไงครับ ให้อัพเดทเป็นวันที่เราต้องการ




ผมเขียนแบบนี้ครับ ไม่รู้ถูกหรือเปล่า

Private Sub Cmd_Report_Up_Click()

If MsgBox("คุณต้องการบันทึกยอดขาย ใช่ หรือ ไม่", vbInformation + vbYesNo, "แจ้งเตือน") = vbYes Then
CurrentDb.Execute "INSERT INTO Report_Sale(R_DATE, R_PRICE, R_SALE, R_CARD,R_CREDIT,R_IN_CREDIT,R_GP) " & _
"values('" & Me.Date_Re & "','" & Me.t01 & "','" & Me.t02 & "','" & Me.t03 & "','" & Me.t04 & "','" & Me.t05 & "','" & Me.t06 & "')", dbFailOnError

End If
End Sub

ถ้าผมต้องการใส่เงื่อนไขวันที่แบบนี้มัน Error ครับ

Private Sub Cmd_Report_Up_Click()

If MsgBox("คุณต้องการบันทึกยอดขาย ใช่ หรือ ไม่", vbInformation + vbYesNo, "แจ้งเตือน") = vbYes Then
CurrentDb.Execute "INSERT INTO Report_Sale(R_DATE, R_PRICE, R_SALE, R_CARD,R_CREDIT,R_IN_CREDIT,R_GP) " & _
"values('" & Me.Date_Re & "','" & Me.t01 & "','" & Me.t02 & "','" & Me.t03 & "','" & Me.t04 & "','" & Me.t05 & "','" & Me.t06 & "')", dbFailOnError
WHERE R_DATE = Me.Date_Re

End If
End Sub

ไม่ทราบว่าต้องเขียนอย่างไงครับ แนะนำด้วยครับ อาจารย์ สันติสุข

[สันติสุข]

"... แต่มันบันทึกเป็นไฟล์ใหม่ ผมอยากให้มันมันทึกซ้ำวันที่อันเดิมครับ ..." เข้าใจว่าบันทึกเป็นเรคคอร์ดใหม่ใช่ไหม คงไม่ใช่ไฟล์ใหม่อย่างที่คุณเขียน แล้วต้องการบันทึกทับของเดิมใช่ไหมครับ

คำสั่ง INSERT INTO เป็นคำสั่งเขียนเรคอร์ดใหม่ครับ  ถ้าจะเขียนทับหรือแก้ไขเรคอร์ดที่มีอยู่แล้ว ต้องใช้คำสั่ง UPDATE ซึ่งมี syntax คือ

โค๊ด: [Select]

UPDATE ชื่อเทเบิล SET ชือฟิลด์1 = ค่าใหม่, ชือฟิลด์2 = ค่าใหม่, ... WHERE เงื่อนไขแต่การเขียนทับ/แก้ไขเรคอร์ดโดยยังไม่มีเรคอร์ดนั้นมาก่อนตามเงื่อนไขที่ใส่หลัง WHERE  ผลก็คือจะไม่มีเรคอร์ดอะไรถูกแก้ไขเช่นกัน (ส่วนคำสั่ง INSERT จะไม่มี WHERE clause ครับ)

ดังนั้นที่ควรเป็นก็คือ หาโดยคำสั่ง SELECT ก่อนว่ามีเรคอร์ดนั้นหรือยัง ถ้ายัง ก็ให้ INSERT ไม่เช่นนั้นก็ให้ UPDATE 

โค๊ด: [Select]

Private Sub Cmd_Report_Up_Click()

If MsgBox( ...... ) = vbYes Then
   If CurrentDB.OpenRecordset("SELECT * FROM Report_Sale WHERE R_DATE = '" & Me.Date_Re & "'").EOF Then
      CurrentDB.Execute "INSERT INTO Report_Sale(R_DATE, R_PRICE, R_SALE,R_CARD,R_CREDIT,R_IN_CREDIT,R_GP) " & _
      "VALUES ('" & Me.Date_Re & "', " & Me.t01 & ", " & Me.t02 & ", " & Me.t03 & ", " & Me.t04 & ", " & Me.t05 & ", " & Me.t06 & ")", dbFailOnError
   Else
      CurrentDB.Execute "UPDATE Report_Sale SET R_Price = " & Me.t01 & ",   .....   = " & Me.t06 & " WHERE R_DATE = '" & Me.Date_Re & "'", dbFailOnError
   End If
End If
End Sub
หมายเหตุ
1. ตรงที่เขียน .... คุณไปเติมเองนะครับ
2. ยังคงใช้เครื่องหมาย ' เป็นตัวครอบชนิดข้อมูลวันที่ เพราะถ้าใช้ # ในกรณีวันที่เป็นปี พ.ศ. จะวุ่นวายมาก คำสั่ง SQL จะใช้ปี ค.ศ. เท่านั้น ถ้าจะใช้ # จริง ก็ต้องแปลงข้อมูลจากหน้าฟอร์มที่เป็นปี พ.ศ. ให้เป็นปี ค.ศ. อีก แต่การใช้ ' มันจะแปลงเอง แต่กฏเกณฑ์การแปลงเป็นยังไงนี่ผมไม่รู้ อาจเกิดปัญหาตรงไหนผมบอกไม่ได้   ยังไงก็ตาม ผมไม่แนะนำให้ตั้งปฏิทินของวินโดว์ในระบบปี พ.ศ. หรือป้อนข้อมูลเป็นปี พ.ศ. เพราะจะทำให้เกิดข้อผิดพลาดแอบแฝงเอาไว้ได้ โปรแกรมอาจตีความต่างจากที่เราเข้าใจได้ ควรตังเป็นปี ค.ศ.และรูปแบบเป็น ว/ด/ป เท่านั้น และจะใช้ # ได้อย่างไม่ต้องกังวล(เท่าไหร่)
3. แต่ถ้าปัจจุบันระบบวินโดว์เป็นปี ค.ศ. อยู่แล้ว แปลว่าปีของ 23/2/2561 คือปี ค.ศ. 2561 นะครับ ไม่ใช่พ.ศ. 2561

[สันติสุข]

ลืมไป อีกวิธีที่ดูง่ายดีก็คือ ลบของเก่าก่อนแล้วค่อยเพิ่มรายการใหม่เข้าไป คำสั่งลบ คือ

โค๊ด: [Select]

DELETE * FROM ชื่อเทเบิล WHERE เงื่อนไข

โค๊ด: [Select]

If MsgBox( ...... ) = vbYes Then
   CurrentDB.Execute "DELETE * from Report_Sale WHERE R_DATE = '" & Me.Date_Re & "'", dbFailOnError
   CurrentDB.Execute "INSERT ... ", dbFailOnError
End If

[nainumgame]

ขอคุณอาจารย์ครับ ผมลองทั้งสองวิธีแต่มันติด error ทั้งสองแบบเลยครับ ไม่ทราบว่ามันเป็นเพราะอะไร ผมงงมากเลยครับคิดไม่ออกเลยครับ








รบกวนด้วยครับ

[สันติสุข]

ลองเปลี่ยนจาก
= '" & Me.Date_Re & "'"
เป็น
= #" & Me.Date_Re & "#"

[nainumgame]

ขอบคุณครับอาจารย์ ผมลองเปลี่ยนแบบที่อาจารย์แนะนำ มันไม่อัพเดทข้อมูลเดิมครับ แต่มันเพิ่มเป็นข้อมูลใหม่มาอีก ไม่ทราบว่าผมต้องแก้ไขยังไงครับ
ผมหาปัญหาไม่ออกเลยครับว่ามันเป็นเพราะอะไร ยังไงผมรบกวนอาจารย์ช่วยดูให้หน่อยน่ะครับว่าผมใส่ตัวไหนผิด ช่วยแนะนำด้วยครับ ขอบคุณครับ




ตัวโปรแกรมครับ https://1drv.ms/u/s!AsCxhafs7TWdgWFhe0BK7zu05BYG

[สันติสุข]

ทดลองแล้วพบว่าปัญหาเกิดจากระบบปี พ.ศ. ครับ คำสั่งในโค้ดต้องเปลี่ยนเป็นปี ค.ศ.

โค๊ด: [Select]

If MsgBox("คุณต้องการบันทึกยอดขาย ใช่ หรือ ไม่", vbInformation + vbYesNo, "แจ้งเตือน") = vbYes Then
  If CurrentDb.OpenRecordset("SELECT * FROM Report_Sale WHERE R_DATE = #" & DateAdd("yyyy", -543, Me.Date_Re) & "#").EOF Then
   CurrentDb.Execute "INSERT INTO Report_Sale(R_DATE, R_PRICE, R_SALE,R_CARD,R_CREDIT,R_IN_CREDIT,R_GP) " & _
    "VALUES (#" & DateAdd("yyyy", -543, Me.Date_Re) & "#, " & Me.t01 & ", " & Me.t02 & ", " & Me.t03 & ", " & Me.t04 & ", " & Me.t05 & ", " & Me.t06 & ")", dbFailOnError
  Else
   CurrentDb.Execute "UPDATE Report_Sale SET R_Price = " & Me.t01 & ",R_SALE = " & Me.t02 & ", R_CARD = " & Me.t03 & ", R_CREDIT= " & Me.t04 & ", R_IN_CREDIT = " & Me.t05 & ", R_GP = " & Me.t06 & " WHERE R_DATE = #" & DateAdd("yyyy", -543, Me.Date_Re) & "#", dbFailOnError
  End If
End If


[nainumgame]

ขอบคุณมากครับ ทำได้แล้วครับ ตรงที่ต้องการเลยครับ ผมงมหาตั้งนาน สุดท้ายเป็นเพราะ พ.ศ. นี่เอง
ขอบคุณอาจารย์มาก ๆ น่ะครับ

[Ekarat Joolawan]

ไม่เห็นมีข้อมูลอะไรให้ดูเลย

[ปิ่นณรงค์]

ไม่เห็นมีข้อมูลอะไรให้ดูเลย

ด้านบนมีให้ใส่ วันที่ๆ จะแสดงข้อมูลครับ ข้อมูลที่เขาใส่มามีแค่เดือน 1 ถึงเดือน 2 ท่านมากดดูวันที่ปัจจุบันคือเดือน 3 มันเลยไม่โชว์ครับ

[nainumgame]

อ้อครับ ผมก็อปแค่ข้อมูลบางส่วนในฐานข้อมูลผมครับ ไม่สง่วนครับเอาไปลองปรับใช้กับฐานข้อมูลอื่น ๆ ดูครับ

[nainumgame]

ขอสอบถามอาจารย์สันติสุข อีกหน่อยครับ โค้ดที่อาจารย์ให้ ทำไมบางเดือนมันกลับเดือนกลับวันกันครับ
เช่น 1/2/2561 มันจะกลับเป็น 2/1/2561 และอีกหลาย ๆ วันครับไม่ทราบว่าเป็นเพราะอะไรยิ่ง เดือนมีนาคม เป็นทุกตัวเลยครับ





รบกวนหน่อยน่ะครับ ไม่ทราบว่ามันเป็นกับอะไรครับ

[สันติสุข]

คุณไป Control Panel ของวินโดว์ เลือก Region and Language แล้วแคป แทป Formats หน่อย ผมอยากดูว่าเครื่องกำหนดรูปแบบ Short Date และ Long Date เป็นอะไร

[pizza_p]

การใช้เงื่อนไขที่เป็น Date ผมจะไม่ใช้รูปแบบนี้ #dd/mm/yy# ใน Query เลยครับ มันมีปัญหากับการตั้งค่าของวินโดวส์แต่ละเครื่อง
ผมตัดปัญหาโดยการใช้ตัวเลขของ Date แทนครับโดยใช้ CDbl(date_data) เช่น

"[MyFieldDate] = " & CDbl(Me.DateControl)
"[MyFieldDate] < " & CDbl(Me.DateControl)
"[MyFieldDate] Between " & CDbl(Me.DateControl1) & " AND " & CDbl(Me.DateControl2)

[nainumgame]

ขอโทษที่ตอบช้าครับ
Short Date และ Long Date

[สันติสุข]

แก้อีกทีครับ

If MsgBox("คุณต้องการบันทึกยอดขาย ใช่ หรือ ไม่", vbInformation + vbYesNo, "แจ้งเตือน") = vbYes Then
  If CurrentDb.OpenRecordset("SELECT * FROM Report_Sale WHERE R_DATE = #" & Format(DateAdd("yyyy", -543, Me.Date_Re),"mm/dd/yyyy") & "#").EOF Then
   CurrentDb.Execute "INSERT INTO Report_Sale(R_DATE, R_PRICE, R_SALE,R_CARD,R_CREDIT,R_IN_CREDIT,R_GP) " & _
    "VALUES (#" & Format(DateAdd("yyyy", -543, Me.Date_Re),"mm/dd/yyyy") & "#, " & Me.t01 & ", " & Me.t02 & ", " & Me.t03 & ", " & Me.t04 & ", " & Me.t05 & ", " & Me.t06 & ")", dbFailOnError
  Else
   CurrentDb.Execute "UPDATE Report_Sale SET R_Price = " & Me.t01 & ",R_SALE = " & Me.t02 & ", R_CARD = " & Me.t03 & ", R_CREDIT= " & Me.t04 & ", R_IN_CREDIT = " & Me.t05 & ", R_GP = " & Me.t06 & " WHERE R_DATE = #" & Format(DateAdd("yyyy", -543, Me.Date_Re),"mm/dd/yyyy") & "#", dbFailOnError
  End If
End If

ปล. เชื่อผมเถอะ เปลี่ยนระบบจาก พ.ศ. เป็น ค.ศ.