มีคนถามไว้ที่ 
 
http://www.access-programmers.co.uk/forums/showthread.php?s=&threadid=19946 
 
ดังนี้ 
I know how to trap standard MS Access errors where you can have the error trapping code 
search for a particular MS ACCess error number. However, how do you get a 
list of all possible MS Windows error codes so that external events can be 
trapped and resolved. 
 
For example, I ahve a hyperlink field on my form that stores a the PATH to a 
document ie. c:\my documents\thanks.doc If this document is moved or deleted,
 the MS Access application come sback with the following message :  
 
"Unable to open c:\my documents\thanks.doc. Cannot open specified file.  
 
I want to trap this error so I can display a different warning to the user. How is this
achieved? 
 
ต้องการที่จะแสดงข้อความที่กำหนดได้เองสำหรับบอกผู้ใช้เมื่อไม่มีไฟล์เป้าหมายที่อยู่ใน Hyperlink จะทำอย่างไร 
ไม่อยากได้คำเตือนที่ Access มีให้คือ 
"Unable to open c:\my documents\thanks.doc. Cannot open specified file. 
 
ความคิดแรกที่วิ่งเข้ามาในหัวผมก็คือ จะตรวจหาไฟล์เป้าหมายว่ามีอยู่ในห้องที่ระบุไว้หรือไม่ ถ้าไม่มีให้แจ้งข้อความของเราเองเตือน แต่จะทำในฟีลด์ที่เป็นแบบ Hyperlink จะได้หรือเปล่า 
 
หรือจะไม่ใช้ Hyperlink แต่เก็บไฟล์ที่จะ link ไว้เป็น Text แล้วค่อยเรียกเปิดใน Web Browser Control ก็ได้ หรือจะเรียกไปเปิดใน Word เองก็ไม่มีปัญหา เพียงแต่ต้องไปเช็คดูก่อนว่ามีไฟล์เป้าหมายอยู่หรือเปล่า โดยใช้ Dir() 
 
มาถึงจุดนี้ทำให้ผมนึกถึงฟังก์ชันเปิดไฟล์ต่างๆ ที่ลงทะเบียนไว้ในเครื่องคอมฯ แล้ว ผมเอามาจากของ Microsoft เคยใชงานมาแล้วหลายครั้ง 
 
โค้ดมีดังนี้ครับ 
 
Declare Function ShellExecute Lib "shell32.dll" Alias _ 
    "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation _ 
    As String, ByVal lpFile As String, ByVal lpParameters _ 
    As String, ByVal lpDirectory As String, ByVal nShowCmd _ 
    As Long) As Long 
 
Global Const SW_SHOWNORMAL = 1 
 
Function StartDoc(DocName As String) 
 
On Error GoTo StartDoc_Error 
 
StartDoc = ShellExecute(Application.hWndAccessApp, "Open", DocName, _ 
    "", "C:\", SW_SHOWNORMAL) 
Exit Function 
 
StartDoc_Error: 
MsgBox "Error: " & Err & " " & Error 
Exit Function 
 
End Function 
 
ถ้าไฟล์เป้าหมายอยู่ในห้องเดียวกับไฟล์ db ที่เรียกใช้งาน ไม่ต้องระบุ path ก็ได้ครับ 
 
ผมเคยเอาไปตอบไว้ที่ http://www.quicktechusa.com/msgboard/wwwboard.pl?read=18079 ครั้งหนึ่งครับ 
      
คราวนี้ก็มาถึงการตรวจหาไฟล์เป้าหมายว่ามีอยู่หรือไม่ โดยใช้ Dir() ถ้ามีก็ให้เปิดไฟล์นั้นเลย แต่ถ้าไม่เจอ ก็ให้แจ้งบอกด้วยข้อความของเราเอง ทำได้ด้งนี้ครับ 
 
Public Function fOpenFile(strFileNamePath As String) 
If Len(strFileNamePath) <> 0 Then 
    If Dir(strFileNamePath) <> "" Then 
        StartDoc strFileNamePath 
        'FollowHyperlink strFileNamePath 
    Else 
        MsgBox "หาไฟล์ '" & strFileNamePath & "' ไม่เจอ", vbOKOnly, "Not found" 
        Exit Function 
    End If 
End If 
End Function 
 
แล้วความคิดที่ 1 หล่ะ จะทำได้มั๊ย ใช้หลังการเดียวกัน แต่จะซับซ้อนหน่อยหนึ่ง 
เริ่มจาก การไปแยกเอาชื่อไฟล์เป้าหมายออกจากฟีลด์ Hyperlink ที่เก็บชื่อไฟล์ไว้ ซึ่งจะอยู่ในรูปแบบเฉพาะ คือ มีเครื่องหมาย # กั้นหน้ากันหลังอยู่ ในหลายๆ รูปแบบดังนี้ 
#c:/workfile/text.txt# หรือ 
text.txt#c:/workfile/text.txt# หรือ 
mypresentation#d:/present.ppt#2 
 
ดูเพิ่มเติมเกี่ยวกับหัวข้อ HyperlinkAddress Property ใน Help ของ Access ได้ครับ 
 
จากตัวอย่างโค้ดข้างล่าง ผมจะใช้ Mid() และ Instr() เข้าช่วยกระเทาะเอาชื่อไฟล์ออกมาครับ ดังนี้ 
... 
    strFile = Me.SiteLink 
    strFile = Mid(strFile, InStr(strFile, "#") + 1) 
    strFile = Left(strFile, InStr(strFile, "#") - 1) 
... 
 
ผมเริ่มเขียนโค้ดดูในส่วนของ On Click ของ Text Box ที่เก็บฟีลด์ Hyperlink ปรากฎว่ายังมีข้อความของ Access แสดงขึ้นมาเหมือนเดิม แล้วจะทำอย่งไรดีหล่ะ ทำงัยให้สามารถหยุดข้อความของ Access ได้  
 
ผมนึกถึงคำสั่ง DoCmd.CancelEvent  
ลองใส่ไป ก็ยังไม่ได้ 
 
พอไปอ่าน Help ในหัวข้อ CancelEvent ดู เลยได้ไอเดียใหม่ ลองใช้กับ On MouseDown ของ Form ดู โดยใช้โค้ดนี้ 
 
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single) 
Dim strFile As String 
'DoCmd.CancelEvent 
On Error GoTo myms 
If Me.ActiveControl = "SiteLink" Then 
If Me.SiteLink <> "" Or Not IsNull(Me.SiteLink) Then 
    strFile = Me.SiteLink 
    strFile = Mid(strFile, InStr(strFile, "#") + 1) 
    strFile = Left(strFile, InStr(strFile, "#") - 1) 
    Caption = strFile 
    If Dir(strFile) <> "" Then 
        'StartDoc strFile 
        FollowHyperlink strFile 
    Else 
myms: 
        MsgBox "หาไฟล์ '" & strFile & "' ไม่เจอ", vbOKOnly, "Not found" 
        Exit Sub 
        DoCmd.CancelEvent 
    End If 
End If 
End If 
End Sub 
 
ไม่เวิรค์แฮะ No Luck!!!! 
 
ผมคิดว่าคงเป็นเพราะบันทัดนี้ยังไม่ทำงานครับ 
... 
If Me.ActiveControl = "SiteLink" Then 
... 
เพราะโฟกัสยังไม่อยู่ใน Text Box เป้าหมายเลย 
 
เลยทดสอบดูว่า DoCmd.CancelEvent ใน On MouseDown จะหยุด Event อื่นถัดไปได้มั๊ย ที่ผมต้องการหยุดคือ On Click นั่นเอง 
 
ผมลองไปใช้กับ Text Box เป้าหมายดู 
 
Private Sub SiteLink_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single) 
    DoCmd.CancelEvent 
End Sub 
 
Bingo!! ใช้ได้ครับ 
 
ด้วยโค้ดข้างล่างนี้เลย 
 
Private Sub SiteLink_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single) 
Dim strFile As String 
DoCmd.CancelEvent 
If Me.SiteLink <> "" Or Not IsNull(Me.SiteLink) Then 
    strFile = Me.SiteLink 
    strFile = Mid(strFile, InStr(strFile, "#") + 1) 
    strFile = Left(strFile, InStr(strFile, "#") - 1) 
 
    If Dir(strFile) <> "" Then 
        'StartDoc strFile 
        FollowHyperlink strFile 
    Else 
        MsgBox "หาไฟล์ '" & strFile & "' ไม่เจอ", vbOKOnly, "Not found" 
        Exit Sub 
        DoCmd.CancelEvent 
    End If 
End If 
 
End Sub 
*** Edited by Supap Chaiya *** 1/4/2546 21:48:24