ฟังก์ชั่น Barcode (39, 128, EAN-8, EAN-13)

Barcode39

- เป็น Barcode แบบมาตรฐานธรรมดา ไม่มีการบีบข้อมูลให้แคบลง ทำให้บาร์โค๊ตที่ได้จะมีความยาวมาก
- ลักษณะการแปลงข้อมูลจะเป็นการแปลงแบบตรงๆ โดยใส่เครื่องหมาย * คร่อมที่หัวและท้ายข้อมูลเพียงเท่านั้น เช่น ABC123 = *ABC123*
- อักษรที่รองรับได้แก่: 0-9, A-Z, - + . $ % / SPACE



1. ติดตั้งฟอนต์ชื่อ free3of9.ttf ลงในส่วนของ MS Windows โดยคลิ๊กขวาที่ตัวไฟล์ฟอนต์ แล้วเลือกหัวข้อ Install (โหลดไฟล์ฟอนต์ที่นี่ Barcode39.zip)

2. ใส่โค๊ดลงใน Module ดังนี้:

'----------------Function Start----------------
Public Function Code39(c39 As String)
    Dim Counter As Integer    
    If Len(c39) > 0 Then
        c39 = UCase(c39)
        For Counter = 1 To Len(c39)
            Select Case Asc(Mid(c39, Counter, 1))
               Case 32, 36, 37, 43, 45 To 57, 65 To 90
               Case Else
                    MsgBox "Invalid character in barcode string." & vbCrLf & vbCrLf & "Only use 0-9, A-Z, - + . $ % / and the SPACE character", vbCritical
                    Code39 = ""
                    Exit Function
            End Select
        Next
    End If
    Code39 = "*" & c39 & "*"
End Function
'-----------------Function End-----------------

3. บนฟอร์ม หรือ รายงาน ให้สร้าง Textbox ที่ต้องการแสดง Barcode39 โดยกำหนดฟอนต์ให้เป็นชื่อ Free 3 of 9 (ที่ได้ทำไว้ตามข้อ 1 โดยหากไม่พบชื่อให้ปิดโปรแกรม MS Access แล้วเปิดใหม่อีกครั้ง)

4. กรณีใช้งานฟังก์ชั่นโดยการกำหนด Property > Control Source: =Code39([txtCode])
- หรือ หากใช้เป็นแบบเขียนใน VBA: Text1 = Code39("ABC1234567890")
-----------------------------------------------------------------------------------------------

Barcode128 Auto

- Code128 สามารถเข้ารหัสทำให้ข้อมูลแคบลงกว่า Code39 ซึ่งเป็นแบบไม่เข้ารหัส ได้ประมาณ 30%
- Code128 แบ่งเป็น 3 ประเภทดังนี้:

Code128A - ASCII without lowercase characters
Code128B - ASCII without the initial ASCII special characters
Code128C - Numeric

- ส่วนของ Code128 Auto คือ โค๊ดที่รองรับทั้ง Code128 A และ B และ C (ดังนั้นจึงแนะนำให้ใช้ เพราะมีความยืดหยุ่นสูง)
Code128 Auto - Support Code 128 A/B/C characters. Automatically switch between the different code sets and performs characters optimization



1. ติดตั้งฟอนต์ชื่อ code128.ttf ลงในส่วนของ MS Windows โดยคลิ๊กขวาที่ตัวไฟล์ฟอนต์ แล้วเลือกหัวข้อ Install (โหลดไฟล์ฟอนต์ที่นี่ Barcode128.zip)

2. ใส่โค๊ดลงใน Module ดังนี้:
'----------------Function Start----------------
Option Explicit

Public Function Code128(SourceString As String)
    Dim Counter As Integer
    Dim CheckSum As Long
    Dim mini As Integer
    Dim dummy As Integer
    Dim UseTableB As Boolean
    Dim Code128_Barcode As String
   
    If Len(SourceString) > 0 Then
        For Counter = 1 To Len(SourceString)
            Select Case Asc(Mid(SourceString, Counter, 1))
               Case 32 To 126, 203
               Case Else
                    MsgBox "Invalid character in barcode string." & vbCrLf & vbCrLf & "Please only use standard ASCII characters", vbCritical
                    Code128 = ""
                    Exit Function
            End Select
        Next
        Code128_Barcode = ""
        UseTableB = True
        Counter = 1
        Do While Counter <= Len(SourceString)
            If UseTableB Then
               mini = IIf(Counter = 1 Or Counter + 3 = Len(SourceString), 4, 6)
               GoSub testnum
               If mini% < 0 Then 'Use Table C
                    If Counter = 1 Then
                        Code128_Barcode = Chr(205)
                    Else 'Switch to table C
                        Code128_Barcode = Code128_Barcode & Chr(199)
                    End If
                    UseTableB = False
               Else
                    If Counter = 1 Then Code128_Barcode = Chr(204) 'Starting with table B
               End If
            End If
            If Not UseTableB Then
               mini% = 2
               GoSub testnum
               If mini% < 0 Then 'OK for 2 digits, process it
                    dummy% = Val(Mid(SourceString, Counter, 2))
                    dummy% = IIf(dummy% < 95, dummy% + 32, dummy% + 100)
                    Code128_Barcode = Code128_Barcode & Chr(dummy%)
                    Counter = Counter + 2
               Else
                    Code128_Barcode = Code128_Barcode & Chr(200)
                    UseTableB = True
               End If
            End If
            If UseTableB Then
               Code128_Barcode = Code128_Barcode & Mid(SourceString, Counter, 1)
               Counter = Counter + 1
            End If
        Loop
        For Counter = 1 To Len(Code128_Barcode)
            dummy% = Asc(Mid(Code128_Barcode, Counter, 1))
            dummy% = IIf(dummy% < 127, dummy% - 32, dummy% - 100)
            If Counter = 1 Then CheckSum& = dummy%
            CheckSum& = (CheckSum& + (Counter - 1) * dummy%) Mod 103
        Next
        CheckSum& = IIf(CheckSum& < 95, CheckSum& + 32, CheckSum& + 100)
        Code128_Barcode = Code128_Barcode & Chr(CheckSum&) & Chr$(206)
    End If
    Code128 = Code128_Barcode
    Exit Function
     
testnum:
        mini% = mini% - 1
        If Counter + mini% <= Len(SourceString) Then
            Do While mini% >= 0
               If Asc(Mid(SourceString, Counter + mini%, 1)) < 48 Or Asc(Mid(SourceString, Counter + mini%, 1)) > 57 Then Exit Do
               mini% = mini% - 1
            Loop
        End If
        Return
End Function
'-----------------Function End-----------------

3. บนฟอร์ม หรือ รายงาน ให้สร้าง Textbox ที่ต้องการแสดง Barcode128 โดยกำหนดฟอนต์ให้เป็นชื่อ Code 128 (ที่ได้ทำไว้ตามข้อ 1 โดยหากไม่พบชื่อให้ปิดโปรแกรมแล้วเรียกใหม่อีกครั้ง)

4. กรณีใช้งานฟังก์ชั่นโดยการกำหนด Property > Control Source: (txtCode คือ รหัสที่ต้องการจะแปลงเป็น Barcode128)
=Code128([txtCode])
หรือ หากใช้เป็นแบบเขียนใน VBA:
Text1 = Code128("ABC-1234567890")